VOV CGI Procedures

• Writing the CGI script as a Tcl script;
• Using the VOV procedures described in this document

HTTP/1.0 200 OK

Content-Type:  text/html
Content-Length: the length of the HTML pagetext of the HTML page

Example -- Basic "Hello, World" CGI script

This script exploits a difference between the handling of comments in the Tcl language, and C-shell to produce an executable script written in Tcl. The C-shell starts, using -f to specify not reading your ~/.cshrc file, and then immediately executes the VOV 'vovsh' program, which is a Tcl-language shell. That program then receives the remainder of the file as a Tcl script. The Tcl interpreter sees the 'exec' line as a comment, but C-shell does not, and executes it.

Note: The -*- on either side of the word 'Tcl' allows Emacs to recognize the file as a Tcl script.

#!/bin/csh -f
# For the -*- Tcl -*- interpreter the next line is a comment\
exec vovsh -f $0 $*

# This file is provided by the VOV install as $VOVDIR/etc/cgi/ciaobello.cgi
#
# Once you have created a project using 'vovproject create' and enabled it
# in your shell using 'vovproject enable your-project-name', you may use
#   vovbrowser
# to find the port on which your project's server listens for HTTP requests.
#
# You may view this CGI program's output by pointing your browser to the URL 
#   http://your-server-host:your-project-port/cgi/ciaobello.cgi

VOVHTML_START                                     ;# start a new page
HTML {                                            ;# begin the page's HTML
    HEAD { TITLE "Ciao bello example" }           ;# set page title
    BODY {                                        ;# begin page body
        H1 { OUT "CIAO BELLO" }                   ;# "Ciao bello" is hello world in Italian
        H3 { OUT "It is now [clock format [clock seconds]]" }
        TABLE {
            TR {                                  ;# first table row is the table hdr
                TH { OUT "Example of a simple CGI script with VOV." } 
            }
            TR BGCOLOR="white" {                  ;# second table row, white background
                TD {                              ;# only 1 table data cell is in this row
                    SMALL {                       ;# make the following text smaller
                        PRE {                     ;# and preformatted in teletype font
                            set fp [open $argv0]  ;# open the file of this script
                            OUT [read $fp]        ;# insert its text into the page
                            close $fp             ;# close file nicely
                        }
                    }
                }
            }
        }       
    }
} 
VOVHTML_FINISH                                    ;# finish the page

Example -- Retrieving VOV Project Information

You can use VOV's Tcl API vtk_* procedures to get information from your project's flow. A nodeid is an integer which is VOV's internal database ID for an object.

Here is a simple example that also shows a way to generate tables.

#!/bin/csh -f
# For the -*- Tcl -*- interpreter the next line is a comment\
exec vovsh -f $0 $*

# This script responds to a URL of type: /cgi/getnode.cgi?nodeid
# see comments in preceding example for how to connect to your project's server
set id [shift]

VOV_HTML_START 
HTML {
    HEAD { TITLE "Get Node $id" } 
    BODY {
        H1 { OUT "Node $id" }
        set nodeInfo [vtk_node_get $id]
        TABLE {
            foreach field { status barrier timestamp type } {
                TR {
                    TH { OUT $field }
                    TD { OUT [shift nodeInfo] }
                }
            }
        }
        OUT "CIAO BELLO"
    }
} 
VOV_HTML_FINISH